Modification in the CODE to HIDE rows and columns that start with ZERO (code given)

[Thulasiram]

Hello all,

I have been trying to manipulate the code given below to hide the rows
and columns that begin with the number ZERO. But, I am landing into
some sort of error.
I know that the code given below works perfectly to hides any empty row
and column.

Can I know if there is any function or command button code that can be
written to hide the rows and columns that begin with the number ZERO?
(ZERO will be found both in column A and 1st row.) If yes, please help
me with the code.

In other words, when the user hits the command button, all the rows and
columns that begin with 0 (ZERO) should be hidden.

Thanks,
Thulasiram.

Private Sub Hide_Click()
Dim SH As Worksheet
Dim col As Range
Dim rw As Range

Set SH = ActiveSheet

For Each col In SH.UsedRange.Columns
col.Hidden = Application.CountA(col) = 0
Next col

For Each rw In SH.UsedRange.Rows
rw.Hidden = Application.CountA(rw) = 0
Next rw
End Sub

 

[Don Guillett]

try
Sub ifzero()
For Each c In Selection
MsgBox Left(c, 1)
If Left(c, 1) = "0" Then c.EntireRow.Hidden = True
Next
End Sub

 

[Thulasiram]

Dear Don Guillett,

Thanks for your response.

The code given by you works perfectly, when the user selects the range.
But, I would like to have the code the situation expalined in my
previous mail.

"when the user hits the command button, all the rows and
columns that begin with 0 (ZERO) should be hidden."

So, the user's job is to just hit the command button and not to select
the cells.

Also the code given by you hides the rows but not the columns.

Please help.

Thanks,
Thulasiram

 

[Tom Ogilvy]

Sub ABC()
Dim r as Range, r1 as Range, r2 as Range
Dim cell as Range
set r = Activesheet.UsedRange
set r1 = Intersect(columns(1),r.EntireRow).cells
set r2 = Intersect(rows(1),r.EntireColumn).Cells
for each cell in r1
if left(cell,1) = "0" then cell.EntireRow.Hidden = True
Next
for each cell in r2
if left(cell,1) = "0" then cell.EntireColumn.Hidden = True
Next
End Sub

 

[Thulasiram]

Dear Tom Ogilvy,

You are the man!

You really rock. Your codes are perfect.

Thanks a ton,
Thulasiram.