Growl notification?

H

Hans Muenchen

Hello,

I'm using here Entourage 2004, SpamSieve 2.6.6 and Growl 1.1.2.
What I must do that new messages (but not the spam messages) will be shown
by growl?

Thanks for your help and the answers.
 
D

Diane Ross

I'm using here Entourage 2004, SpamSieve 2.6.6 and Growl 1.1.2.
What I must do that new messages (but not the spam messages) will be shown
by growl?
Click to expand...

Entourage doesn't support Growl. I've suggested this addition myself. The
more people that ask for this, the better chance we will get it added. Send
Feedback under Help in the Menu bar.

I use custom sounds to notify me of special mail.

See this page for using custom sounds with Entourage. You can even create
your own sounds or use computer voices to announce your mail. For example,
you could have the AppleScript say ³Mail from Dad², "Buddy", or "Work".

Rule to Play Sound

<http://www.entourage.mvps.org/rules/sounds.html>
 
J

Jon Connell

Diane said:
Entourage doesn't support Growl. I've suggested this addition myself. The
more people that ask for this, the better chance we will get it added. Send
Feedback under Help in the Menu bar.
Click to expand...

Not natively it doesn't and there are various implementations about. I
started with one from scriptbuilders.net (from [email protected]), but I
didn't like some of its behaviour, so I tweaked it a bit.

Place this script in your Entourage Scripts folder and add a new rule on
all incoming mail that runs this script (as the last rule in the list).

Jon


tell application "GrowlHelperApp"
set the allNotificationsList to {"New Mail"}
set the enabledNotificationsList to {"New Mail"}
register as application ¬
"Entourage" all notifications allNotificationsList ¬
default notifications enabledNotificationsList ¬
icon of application "Microsoft Entourage"
end tell

tell application "Microsoft Entourage"
set theMessages to the current messages
end tell
repeat with theMsg in theMessages
tell application "Microsoft Entourage"
set mysubject to get the subject of theMsg
set mysender to the display name of sender of theMsg as string
if mysender is "" then
set mysender to the address of sender of theMsg as string
end if
end tell
tell application "GrowlHelperApp"
notify with name "New Mail" title "You have new email" description
("From " & mysender & " about " & mysubject) application name "Entourage"
end tell
end repeat
 
J

Jon Connell

Or with a preview of the message:

tell application "GrowlHelperApp"
set the allNotificationsList to {"New Mail"}
set the enabledNotificationsList to {"New Mail"}
register as application ¬
"Entourage" all notifications allNotificationsList ¬
default notifications enabledNotificationsList ¬
icon of application "Microsoft Entourage"
end tell

tell application "Microsoft Entourage"
set theMessages to the current messages
end tell
repeat with theMsg in theMessages
tell application "Microsoft Entourage"
set mysubject to get the subject of theMsg
set mysender to the display name of sender of theMsg as string
if mysender is "" then
set mysender to the address of sender of theMsg as string
end if
set AppleScript's text item delimiters to return
set theContent to the content of theMsg
set lineCount to 0
set thePreview to ""
repeat with theLine in text items of theContent
set lineCount to lineCount + 1
if lineCount > 3 then exit repeat
set thePreview to thePreview & return & theLine
end repeat
set AppleScript's text item delimiters to ""
end tell
tell application "GrowlHelperApp"
notify with name ¬
"New Mail" title (mysubject & return & "From: " & mysender) ¬
description thePreview ¬
application name "Entourage"
end tell
end repeat
 
C

Corentin Cras-Méneur

Hans Muenchen said:
I'm using here Entourage 2004, SpamSieve 2.6.6 and Growl 1.1.2.
What I must do that new messages (but not the spam messages) will be shown
by growl?
Click to expand...


I thought it could be achieved without any additional effort through
SpamSieve....


Corentin
 
Top