Only Showing Changed Bullets in a Legal Doc

[Jonathan]

I do a lot of contract negotiation which involves sending
a Word document (a standard contract) to a vendor and then
reviewing their mark ups. The document gets passed back
and forth several times as we work toward agreement on the
bullet points that the vendor has issues with.

The standard contract is 31 pages long, formatted into
sections with bullet points. We typically only negotiate
two pages of bullet points. It is very cumbersome working
with the 31 page document.

Is there a way to search the document for bullet points
with changes and then only show those bullet points with
changes?

Thanks,

Jonathan

 

[Leigh Webber]

Why not use the Reviewing toolbar and the Track Changes feature? No VBA
necessary.

 

[Jonathan]

I do use the Reviewing toolbar. It's very helpful, but
doesn't offer a view of only the changes. My document
size is still 31 pages. I'd like a view of the document
that would be more like 2 pages.

Searching for a parameter and then hiding everything that
doesn't fit a condition of the parameter is a simple thing
to do in Excel. I'm basically trying to figure out how to
search for changes and then return the full bullets that
have any change. I write VBA in Excel and Access, I'm
struggling with my first Word program.

How do you identify change? How do you return a full
bullet?

Thanks,

Jonathan

 

[Leigh Webber]

A nifty challenge. Try something like this (use a scratch copy of the
document, of course):

Sub ShowOnlyChangedParas()
Dim llFirstChangeStart As Long

With ActiveWindow
'Make sure inivisibles are showing
.ActivePane.View.ShowAll = True
'No balloons
.View.RevisionsMode = wdInLineRevisions
End With
'Turn off track changes
ActiveDocument.TrackRevisions = False

'Mark all document text as hidden
ActiveDocument.Range.Font.Hidden = True

With Selection
'Go to the top of the document
.HomeKey Unit:=wdStory
'Find and select the first change
WordBasic.NextChangeOrComment
'Note its start
llFirstChangeStart = .Start
Do
'Extend the selection to the start of the
'first para in the selection
.Start = .Paragraphs(1).Range.Start
'And extend the end to the end of the last
'para in the selection
.End = .Paragraphs(.Paragraphs.Count).Range.End
'Unhide
.Font.Hidden = False
'Collapse to the end of the selection and ...
.Collapse wdCollapseEnd
'...select the next change.
WordBasic.NextChangeOrComment
'When all are found, NextChangeOrComment wraps
'back to the beginning
Loop Until Selection.Start <= llFirstChangeStart
End With
'Hide the hidden text, leaving only the changed paras visible
ActiveWindow.ActivePane.View.ShowAll = False
End Sub