When I compose a new mail message, and I click on a contact from my
address book, how can I get all email addresses associated with that
contact to be put in the To line, instead of just the one address that is
marked as the default address. Is there a way to turn that default off?
There is no way to "turn off " a default address. What would the program
then do? Prompt you to choose an address every time you sent this person
mail? How is that more convenient that having the most common address as the
default, with the others available in the autocompletion menu that pops up?
Here is a script that will send a message to all the addresses of a given
contact, if you first select the contact in the Address Book (or, if not,
you type in the person's full name or e-mail address):
--Set up outgoing message to every address of a contact
tell application "Microsoft Entourage"
activate
set whatsSelected to the selection
try
if class of whatsSelected is list then
if (count whatsSelected) > 0 then
set whatsSelected to item 1 of whatsSelected
end if
end if
on error
set whatsSelected to ""
end try
if class of whatsSelected is contact then
set theContact to whatsSelected
else
display dialog ¬
"Enter the name or one complete email address of the contact you
wish to address." default answer ""
set {btn, txt} to {button returned, text returned} of result
if btn is "Cancel" then return
set theInput to txt
try
if theInput contains "@" then -- Assume we have an e-address
set theContact to find theInput
else -- Assume it's a name
set theContact to contact theInput
end if
on error theErr
display dialog theErr
return
end try
end if
set theList to every email address of theContact
if theList = {} then return
set AppleScript's text item delimiters to ", "
set theList to theList as text
set AppleScript's text item delimiters to ""
make new draft window with properties {to recipients:theList}
end tell
--
Microsoft MVP for Entourage/OE/Word (MVPs are volunteers)
Allen Watson <
[email protected]> Entourage FAQ site:
<
http://www.entourage.mvps.org/>
AppleScripts for Outlook Express and Entourage:
<
http://homepage.mac.com/allen_a_watson/FileSharing3.html>
Entourage Help Pages: <
http://www.entourage.mvps.org/>
