Thanks for replying Paul. I did study the dictionary (I'm trying!), but
I did a very poor job of phrasing my question. Apologies.
I am adapting the "Create Task From Message" script to let me choose a
category for the text. I am trying to do something like this (this is a
piece of the script):
-- create a new task with the information from the message
set newTask to make new task with properties {name:theName,
content:theContent, priority:thePriority}
set x to categories
repeat with an_item in x
set the end of catNames to name of an_item
end repeat
-- choose a category from the list
set catChoose to choose from list catNames with prompt "Choose
Category" OK button name "Choose" without multiple selections allowed
and empty selection allowed
if catChoose is not false then
set catChoice to item 1 of catChoose
end if
if catChoice = "@Computer" then
set category of newTask to {category "@Computer"}
end if
I've been able to make it work in the version you see here, and would
then add if/thens for the other categories. Seems kludgey. Is there a
way that I can set the category from the "catChoice" variable without
all the if/then statements?
Yes. Just like that. I'm not quite clear why you didn't do just that, once
you'd already gone to the trouble to get catChoice: just use it. You don't
need that repeat loop, nor the previous one: [property] of every [element]
to get a complete list can always be used in AppleScript. (And it's not
necessary to specify the default values of the 'choose from list'
parameters. However you should allow for 'empty selection' to allow the user
to mean "None of the above", since "None" doesn't appear in the list. Or -
to make it easier for the user, include "None" as an option. You need to put
it in list brackets to concatenate it with the list of all category names.
Similarly using 'is in' (obverse of 'contains') requires the same class
('list' here) on both sides of the 'is in' operator: neater than a run-on of
several 'or' conditions.
tell application "Microsoft Entourage"
-- create a new task with the information from the message
set newTask to make new task with properties {name:theName,
content:theContent, priority:thePriority}
set catNames to {"None"} & name of every category
-- choose a category from the list
set catChoose to choose from list catNames with prompt "Choose Category"
OK button name "Choose" with empty selection allowed
if {catChoose} is not in {false, {}, {"None"}} then
set catChoice to item 1 of catChoose
set category of newTask to {category catChoice}
end if
end tell
--
Paul Berkowitz
MVP MacOffice
Entourage FAQ Page: <
http://www.entourage.mvps.org/faq/index.html>
AppleScripts for Entourage: <
http://macscripter.net/scriptbuilders/>
Please "Reply To Newsgroup" to reply to this message. Emails will be
ignored.
PLEASE always state which version of Microsoft Office you are using -
**2004**, X or 2001. It's often impossible to answer your questions
otherwise.
