SUMIF?

[Perry]

Here is my situation
I have a data range that contains a six-character value. I only care about
the last character

I want to sum the values in I4:I29 where the characters in A4:H29 meet a
certain value

EX: A4 = A00000A; I4 = 2
B10 = B11111A; I10=1
G5 = C12121A; I5 = 1
H29 = D12345A; I5 = 4

I want the sum of the values in I (8) for these cells but not for any others.

I have tried:
=IF(A4:H29=â€*Aâ€,SUM(I4:I29),0)
=SUMIF(A4:H29, “*Aâ€, I4:I29)
=SUM(IF(((A4:A29=â€*Aâ€)+(B4:B29=â€*Aâ€)+(C4:C29=â€*Aâ€)+
(D429=â€*Aâ€)+(E4:E29=â€*Aâ€)+(F4:F29=â€*Aâ€) +(G4:G29=â€*Aâ€)), SUM(I4:I29),0)
=IF(RIGHT(A4:A29)="N",SUM(I4:I39),0)

All of the above formulas return the value 0 (false)

On the same worksheet the following formula works:
COUNTIF(A4:H29,â€*Aâ€)

Any suggestions?

 

[T. Valko]

If a row contains more than one entry that meets the criteria should that be
calculated as n*I ?

Like this:

xxxA...xxxc...cccA...5

The row contins 2 entries that end in "A". So, should the result add 2*5 =
10 to the total?

 

[Sheeloo]

Enter this in J4
=COUNTIF(A4:H4,"*A") and copy down till J29
Now in I30 enter
=SUMPRODUCT(--(J2:J29>0),I2:I29) to get what you want...

I could not think of a way to combine the above two formulae

 

[ShaneDevenshire]

Hi,

First thing to note is that IF does not support wildcards.

If there are at most one match per row or you want to sum it more than once
if it appears a one row more than once you can use the single formula:

=SUMPRODUCT(NOT(ISERR(SEARCH("?????A",A1:H12)))*I1:I12)

 

[Dave Peterson]

Just to add to Shane's response.

If there are multiple cells in a single row that match that criteria, then the
value in column I will be used for each match.

 

[Perry]

Thank you Shane and Dave. The SUMPRODUCT formula worked like a champ. I will
have to learn a bit more about this formula.
Perry Hill

 

[T. Valko]

A few keystrokes shorter:

=SUMPRODUCT((RIGHT(A4:H29)="A")*I4:I29)

 

[RagDyer]

Just as a topic of conversation, this is a single formula, although no
pretty, that will total each match only once per row:

=SUMPRODUCT((((RIGHT(A4:A29)="A")+(RIGHT(B4:B29)="A")+(RIGHT(C4:C29)="A")+(RIGHT(D429)="A")
+(RIGHT(E4:E29)="A")+(RIGHT(F4:F29)="A")+(RIGHT(G4:G29)="A")+(RIGHT(H4:H29)="A"))>0)*I4:I29)

 

[T. Valko]

A few keystrokes shorter:

=SUMPRODUCT(--(MMULT(--(RIGHT(A4:H29)="A"),{1;1;1;1;1;1;1;1})>0),I4:I29)

Drawback: range is limited to no more than 5461 rows

 

[RagDyer]

Just a few?<bg>