A formula to show Next month

A

AndreL

I looking for a fuction that show next month and not the current month. Cause
the formula I have show the current month which is "=TODAY()". So your help
will be appreciated.
 
S

Stan Brown

I looking for a fuction that show next month and not the current month. Cause
the formula I have show the current month which is "=TODAY()". So your help
will be appreciated.
Click to expand...

What do you mean by "next month"?

The month number?

=MOD(MONTH(TODAY()),12)+1

The first day of the next month?

=EOMONTH(TODAY(),0)+1

The last day of the next month?

=EOMONTH(TODAY(),1)

or something else?
 
A

AndreL

The first one shows "Jun-00" and it shows it that way cause I have the fomat
of the cell setup for dates. And the date type as "Mar-01" And I look on the
Internet to find a way to do the next month from the current formula. What I
have is "Today () +31" and it show the next month form the current. Now will
that in any way not work for months that have either 31 or 30 days.
oh yea and ... thank for you hel Stan The Man.
 
R

Ron Rosenfeld

I looking for a fuction that show next month and not the current month. Cause
the formula I have show the current month which is "=TODAY()". So your help
will be appreciated.
Click to expand...

What do you mean by "next month".

With the date in A1:

The following formula will show the NAME of the next month:

=CHOOSE(MONTH(A1),"Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec","Jan")

The following formula will add one month to the date, but not go past the last
day of the subsequent month.

=edate(A1,1)

--------------------------
If the EDATE function is not available, and returns the #NAME? error, install
and load the Analysis ToolPak add-in.

On the Tools menu, click Add-Ins.
In the Add-Ins available list, select the Analysis ToolPak box, and then click
OK.
If necessary, follow the instructions in the setup program.
------------------------------

Or, without installing the ATP:

=DATE(YEAR(A1),MONTH(A1)+1,DAY(A1))-
IF(DAY(DATE(YEAR(A1),MONTH(A1)+1,DAY(A1)))<DAY(A1),
DAY(DATE(YEAR(A1),MONTH(A1)+1,DAY(A1))))


--ron
 
P

Peo Sjoblom

Try

=DATE(YEAR(A1),MONTH(A1)+1,1)

--
Regards,

Peo Sjoblom

(No private emails please)
 
Top