Auto tag the time in B1 to an entry in cell A!

D

DDavid

Hi guys,

I need to get a solution for this.

If write a data in Cell A1, how can I get in cell B1 the time on what
this data was writen.

Thanks in advance.

ADC
 
M

Mike H

Hi,

Right click your sheet tab, view code and paste this in. Alter A1 - A100 to
suit

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Cells.Count > 1 Or IsEmpty(Target) Then Exit Sub
If Not Intersect(Target, Range("A1:A1000")) Is Nothing Then
Target.Offset(, 1).Value = Time
End If
End Sub

Mike
 
G

Gord Dibben

Event code is a good way to go to get a static time stamp in a cell.

Private Sub Worksheet_Change(ByVal Target As Excel.Range)
'when entering data in any cell in Col A, time into column B
On Error GoTo enditall
Application.EnableEvents = False
If Target.Cells.Column = 1 Then
n = Target.Row
If Me.Range("A" & n).Value <> "" Then
Me.Range("B" & n).Value = Now
End If
End If
enditall:
Application.EnableEvents = True
End Sub

Right-click on the sheet tab and "View Code"

Copy/paste into that module. Edit to suit then Alt + q to return to the
Excel window.


Gord Dibben MS Excel MVP
 
D

DDavid

What is the difference from the last post solution?

Is there a reason for not using any of both?
 
G

Gord Dibben

Both do the same thing.

Type something in column A and get the time in column B

Mike's "Time" will give you just hh:mm:ss

My "Now" will give you date and time.

Depends what you want.

Mike also uses a finite range in column A.........I don't

In my code, disabling events prevents possible infinite looping.

Adding error trap re-enables events in the case of an error

Neither are likely in this case but...................

I just stick it in to be safe.


Gord
 
Top