Averaging compound numbers

O

Old Red One

Is there a formula for obtaining an average of a series of compound numbers,
such as blood pressure readinags, e.g. 140/80?
 
J

JE McGimpsey

What form do you want the results in?

If XXX/YYY then one way is to array enter (CTRL-SHIFT-ENTER or
CMD-RETURN):

=TEXT(AVERAGE(--LEFT(A1:A20,3)),"0") & "/" &
TEXT(AVERAGE(--MID(A1:A20,5,3)),"0")
 
R

Ragdyer

Hey John,

Slight revision to your formula to include a neighbor of mine, who has low
blood pressure, where his systolic number is below 90.

=TEXT(AVERAGE(--LEFT(A1:A5,FIND("/",A1:A5)-1)),"0")&"/"&TEXT(AVERAGE(--RIGHT
(A1:A5,LEN(A1:A5)-FIND("/",A1:A5))),"0")
 
H

Harlan Grove

Ragdyer said:
=TEXT(AVERAGE(--LEFT(A1:A5,FIND("/",A1:A5)-1)),"0")&"/"
&TEXT(AVERAGE(--RIGHT(A1:A5,LEN(A1:A5)-FIND("/",A1:A5))),"0")
Click to expand...
....

OK, but this could be shortened to

=ROUND(AVERAGE(--SUBSTITUTE(A1:A5,"/",".000000")),0)&"/"
&ROUND(AVERAGE(--MID(A1:A5,FIND("/",A1:A5)+1,1024)),0)
 
T

Tushar Mehta

You may also want to consider splitting the data into individual
components and operating on them. Suppose your BP readings are in col.
A starting with A2. Then, in B2, enter =LEFT(A2,FIND("/",A2)-1) to get
the systolic reading. In C2, enter =MID(A2,LEN(B2)+2,LEN(A2)) to get
the diastolic reading. Now, you can do whatever you want with the
components.

--
Regards,

Tushar Mehta
www.tushar-mehta.com
Excel, PowerPoint, and VBA add-ins, tutorials
Custom MS Office productivity solutions
 
Top