Conditional IF

J

Jon1205

I have this equation in the column E cells:

=IF(VLOOKUP(D3,$H$2:$I$17,2,FALSE)>0,VLOOKUP(D3,$H$2:$I$17,2,FALSE)*C3,0)

What I am trying to do is if there is no data in column D cells, I want it
to enter a zero (0). It is currently returning the #N/A error, wich is the
same error if I only had the vlookup () equation.

I want it to return a zero (0) because at the bottom I am summing the
content wich will return #N/A if one cell contains that message.

Thanks for any help
 
F

Fred

Try this:

=IF(ISERROR(VLOOKUP(D3,$H$2:$I$17,2,FALSE)),0,VLOOKUP
(D3,$H$2:$I$17,2,FALSE)*C3)

HTH
Fred
 
M

Minitman

Hey Hon,

Try this:

=IF(D3="",0,IF(VLOOKUP(D3,$H$2:$I$17,2,FALSE)>0,VLOOKUP(D3,$H$2:$I$17,2,FALSE)*C3,0))

Assuming that D3 has nothing in it this would give you a 0 in E3.

HTH

-Minitman
 
B

Biff

Hi!

=IF(ISNA(VLOOKUP(D3,$H$2:$I$17,2,FALSE)),0,VLOOKUP(D3,$H$2:$I$17,2,FALSE)*C3)

You can also use something like this to ignore the #N/A:

=SUMIF(E1:E10,"<>#N/A")

Biff
 
T

Trevor Shuttleworth

Try:

=IF(ISNA(VLOOKUP(D3,$H$2:$I$17,2,FALSE)),0,VLOOKUP(D3,$H$2:$I$17,2,FALSE)*C3)

Regards

Trevor
 
E

eider

I think what you want is
=IF(ISERROR(VLOOKUP(D3,$H$2:$I$17,2,FALSE)),0,VLOOKUP(D3,$H$2:$I$17,2,FALSE)*C3)
 
Top