Create a custom footer for all Excel worksheets at one time...

B

bigcat

I want to create a custom footer, just once, that could be applied to all
worksheets in an Excel workbook. Microsoft Word lets you do this, so why
not Microsoft Excel?
 
D

Dennis

BigCat

Try the code below:

Be sure to substitute the information for what you want.

HTH

Dennis

********************************************

Sub PageSetupAllSheets()

Dim EachSheet As Worksheet
For Each EachSheet In ActiveWorkbook.Worksheets
With EachSheet.PageSetup
' &F = File
' &A = Tab
' &D = Date
' &T = Time
' &P = Page
' &N = Pages
'
' NOTE: the "&8" that you see below is font size
'
' Chr(10) is a carrage return
'
'
.LeftFooter = "&8 &D &T"
.CenterFooter = "&8Your Name" ' & Chr(10) & "&D &T"
.RightFooter = "&8Page " & "&P of &N"
End With
Next EachSheet
MsgBox "Process Completed! Press OK to Continue"
End Sub
 
G

Gord Dibben

bc

Manually.......

Select all worksheets(right-click and select sheets) before setting the
footer.

It will be applied to all sheets.

DO NOT FORGET to ungroup the sheets when done.

Use a macro to set a custom footer to all sheets..........

Sub Path_All_Sheets()
Set wkbktodo = ActiveWorkbook
For Each ws In wkbktodo.Worksheets
ws.PageSetup.RightFooter = ActiveWorkbook.FullName & " " & Chr(13) _
& Application.UserName & " " & Date
Next
End Sub


Gord Dibben Excel MVP
 
Top