Extract list of units based on error criteria to new list

S

Sheila

I have a list that looks like this:
Column A Column B
02941842 34,939.55
02941840 34,939.55
03062084 #N/A
02657582 30,203.20
03126311 #N/A
03105157 28,430.54

I need a seperate summary list that extracts the items from Column A with an
error in Column B. Can excel do this?
 
T

Teethless mama

In D1:
=IF(ISERR(SMALL(IF(ISERROR(rangeB),ROW(INDIRECT("1:"&ROWS(rangeA)))),ROWS($1:1))),"",INDEX(rangeA,SMALL(IF(ISERROR(rangeB),ROW(INDIRECT("1:"&ROWS(rangeA)))),ROWS($1:1))))

ctrl+shift+enter, not just enter
copy down

In E1: =IF(D1="","",VLOOKUP(D1,ranges,2,0))
copy down
 
D

Dave Peterson

Apply data|filter|autofilter to column B.
Filter to show the #n/a's.
Select those visible rows
edit|copy
then off to the new location
edit|paste
 
T

T. Valko

Since they wanted to extract based on #N/A you should probably use:

(SMALL(IF(ISNA(rangeB)

Your error trap is horrendous! <bg>

=IF(ISERR(SMALL(IF(ISERROR(rangeB),ROW(INDIRECT("1:"&ROWS(rangeA)))),ROWS($1:1)))

It can be replaced with:

=IF(ROWS($1:1)<=COUNTIF(rangeB,#N/A)

I give up trying to convince you that this is not the best way to go:

ROW(INDIRECT("1:"&ROWS(rangeA)))
 
T

T. Valko

I need a seperate summary list that extracts the items from Column A with
Since they wanted to extract based on #N/A you should probably use:
(SMALL(IF(ISNA(rangeB)
Click to expand...

Or maybe not. For some reason I read it as extract based on #N/A but
apparently not. So ISERROR would be appropriate.

But the error trap is still horrendous no matter how you slice it! <bg>

So, for all errors:

=IF(ROWS($1:1)<=SUMPRODUCT(--(ISERROR(rangeB)))
 
T

T. Valko

Array entered:

=IF(ROWS($1:1)<=SUMPRODUCT(--ISERROR(rngB)),INDEX(rngA,SMALL(IF(ISERROR(rngB),ROW(rngA)-MIN(ROW(rngA))+1),ROWS($1:1))),"")
 
T

Teethless mama

Stop whinning like a baby? My formula is show on most Excel text books. Read
"Excel 2003 Bible by John Walkenbach" it show a lot of those formulas.
 
T

T. Valko

Stop whinning like a baby?

I'm trying to show you a better way to do things. If you can't appreciate
that then....you're welcome and thanks for the feedback!
 
Top