Find Last Row in Column

S

SIGE_GOEVAERTS

Hi There,

Is it possible with a formula to determine what the last row is in a
certain column which is "Not Empty"?

Brgds Sige
 
T

TemplateBuilder

Hello Sige,

The formula =COUNT(A:A)+1 counts the number off filled cells in the
column. This matches the first row within a the column A that is not
empty.

Hope you find this information useful

gr. TemplateBuilder
 
T

TemplateBuilder

Hello Sige,

The formula =COUNT(A:A)+1 counts the number off filled cells in the
column. This matches the first row within a the column A that is not
empty.

Hope you find this information useful

gr. TemplateBuilder
 
S

SIGE_GOEVAERTS

Hi TemplateBuilder,

Thank you for your solution but that is not exactly what I am after ...

Imagine you have only 5 values filled in Column A ...bu the 5th is at
row 125 then I would like it to return 125 and not 5 (or 6).

Brgds Sige
 
S

SIGE_GOEVAERTS

Aladin,

A column with text- and numerci values. No formulas though.

Brgds Sige
 
R

Roger Govier

Hi

One way
=CELL("Address",INDEX(A:A,MAX(MATCH(99999999,A:A),MATCH("ZZZZ",A:A))))

This will look for the last numeric or last text value in column A and
return the cell reference where found.
Some people use the largest number Excel can handle (9.99999999999999E+307)
in the search for numbers, and REPT("Z",255) for text, but I have usually
found the above to meet my needs.

Regards

Roger Govier
 
A

Aladin Akyurek

Taking column A as target...

1. Focusing only on data that is either numeric or text...

B1:

=MATCH(REPT("z",255),A:A)

B2:

=MAX(CHOOSE({1,2},IF(ISNUMBER(B1),B1,0),MATCH(9.99999999999999E+307,A:A)))

2. Focus is on any value...

=IF(ISBLANK(A65536),MATCH(2,1/(1-ISBLANK(A1:A65535))),65536)

which must be confirmed with control+shift+enter.

This yields the native row number of even an error value if that is the
last value.

Taking in consideration your data types, he first is more efficient.
 
A

Aladin Akyurek

Two notes...

This will fail when there is either no text or no numeric data. BTW, the
OP is asking for the row number, not the address of the last
numeric/text value.

You state:
"Some people use the largest number Excel can handle
(9.99999999999999E+307) in the search for numbers, and REPT("Z",255) for
text, but I have usually found the above to meet my needs."

Maybe so. However, did you consider endless variations the people may
come up with, causing a jungle of constants, hard to explain to new comers?


Roger said:
Hi

One way
=CELL("Address",INDEX(A:A,MAX(MATCH(99999999,A:A),MATCH("ZZZZ",A:A))))

This will look for the last numeric or last text value in column A and
return the cell reference where found.
Some people use the largest number Excel can handle
(9.99999999999999E+307) in the search for numbers, and REPT("Z",255) for
text, but I have usually found the above to meet my needs.

Regards

Roger Govier
Click to expand...

--

[1] The SumProduct function should implicitly coerce the truth values to
their Excel numeric equivalents.
[2] The lookup functions should have an optional argument for the return
value, defaulting to #N/A in its absence.
 
R

Roger Govier

Hi Aladin

Thank you for the notes.
This will fail when there is either no text or no numeric data.
Click to expand...
I had rather assumed, that if the OP had a totally empty column, then he
wouldn't be looking for the last used row, hence the #N/A return from a
totally blank column didn't really seem to be material.
BTW, the OP is asking for the row number, not the address
Click to expand...
Yes, on re-reading the original post, the OP does ask for row and not cell
address. The formula should be amended to

=CELL("Row",INDEX(A:A,MAX(MATCH(99999999,A:A),MATCH("ZZZZ",A:A))))
However, did you consider endless variations the people may come up with,
causing a jungle of constants, hard to explain to new comers?
Click to expand...
No, I didn't. But I did give the formula for a large numeric value or large
text value if the user chose to use those instead.

Neither did I go on to explain that in reality, I use defined names for
large numbers and large text values, which I use in my formulae rather than
having to count how many 9's I am entering every time I use this type of
Lookup, and enabling the call of the REPT() function to be made once, rather
than throughout every formula.

Insert>Name>Define
Name BigN Refers to =9.99999999999999E+307
Name BigT Refers to =REPT("Z",255)
(these were tips I picked up from Bob Phillips)

=CELL("Row",INDEX(A:A,MAX(MATCH(BigN,A:A),MATCH(BigT,A:A))))

I think it is sometimes of more value to the OP to get a rapid answer that
answers their immediate need, rather than wait longer for a comprehensive
answer that suits everyone.

But then again, perhaps I am wrong.<g>

Regards

Roger Govier
 
A

Aladin Akyurek

Roger said:
Hi Aladin

Thank you for the notes.
I had rather assumed, that if the OP had a totally empty column, then he
wouldn't be looking for the last used row, hence the #N/A return from a
totally blank column didn't really seem to be material.
Click to expand...

That is not what I mean: When it's the case that A is all numeric or
when when A is all text, the formula will fail.
Yes, on re-reading the original post, the OP does ask for row and not
cell address. The formula should be amended to

=CELL("Row",INDEX(A:A,MAX(MATCH(99999999,A:A),MATCH("ZZZZ",A:A))))
Click to expand...

Too wordy... said:
with, >causing a jungle of constants, hard to explain to new comers?
No, I didn't. But I did give the formula for a large numeric value or
large text value if the user chose to use those instead.

Neither did I go on to explain that in reality, I use defined names for
large numbers and large text values, which I use in my formulae rather
than having to count how many 9's I am entering every time I use this
type of Lookup, and enabling the call of the REPT() function to be made
once, rather than throughout every formula.

Insert>Name>Define
Name BigN Refers to =9.99999999999999E+307
Name BigT Refers to =REPT("Z",255)
(these were tips I picked up from Bob Phillips)
Click to expand...

I for one often called them: BigNum and BigStr.
 
Top