Find the 1st occurance of a number in a cell

L

lovemuch

The cell's text is:
Reclassed to 101-001-4455-003.
I want to find the position of the first number, which in this case would be
the number "1" and it would be in the 14th place (if I counted right!). The
text will vary, so the locate of the number will vary, and the number itself
will vary.

I should be able to figure this out, but it's become like looking at your
best friend and not being able to remember their name!

Thanks for anyone's assistance!

Yours truly.....Cynthia :)
 
D

David Billigmeier

Commit both of these functions as array formulas (CTRL+SHIFT+ENTER)

To find the position of the first numerical value:

=MATCH(TRUE,ISNUMBER(--(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))),0)

And then to extract that number from the string, use the above formula
embedded in the MID() function:

=MID(A1,MATCH(TRUE,ISNUMBER(--(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))),0),1)
 
L

lovemuch

I was hoping for a much simpler solution using SEARCH, FIND, MID, by using a
wildcard for any number. I just can't find what such a wildcard would be. Is
it "--"? I get the rest of your suggestion, though. Thanks for your help!
 
L

lovemuch

I forgot to do the formula as an array...now it works for me. Just seems a
bit complex! Oh well, if it works!

Thanks, David
 
D

Domenic

If there will always be at least one number within the text string,
try...

=MIN(FIND({0,1,2,3,4,5,6,7,8,9},A2&"0123456789"))

Otherwise, try...

=IF(OR(ISNUMBER(FIND({0,1,2,3,4,5,6,7,8,9},A2))),MIN(FIND({0,1,2,3,4,5,6,
7,8,9},A2&"0123456789")),"")

Hope this helps!
 
Top