finding value

C

ceemo

i have a sheet containing daes in column a, a name in column b and
another name in column c


no column b name will be reeated for each date.

i want to get the name in column c by matching the name in column b and
date in column a


a b c
1/2/6 bob fizz
1/2/6 pete fizz
2/2/6 bob pepsi
2/2/6 steff orange
2/2/6 pete pepsi
3/2/6 bob lemon


from the example i want to use the name bob and the date 2/2/6 to get
orange.
 
D

Dave Peterson

=index(othersheet!$c$1:$c$100,
match(1,(a2=othersheet!$a$1:$a$100)*(b2=othersheet!$b$1:$b$100),0))
(one cell)

This is an array formula. Hit ctrl-shift-enter instead of enter. If you do it
correctly, excel will wrap curly brackets {} around your formula. (don't type
them yourself.)

Adjust the range to match--but you can't use the whole column.

This returns the value in othersheet column C when column A and B (of
othersheet) match A2 and B2 of the sheet with the formula.

And you can add more conditions by just adding more stuff to that product
portion of the formula:

=index(othersheet!$d$1:$d$100,
match(1,(a2=othersheet!$a$1:$a$100)
*(b2=othersheet!$b$1:$b$100)
*(c2=othersheet!$c$1:$c$100),0))
 
C

ceemo

i couldnt get this to work


=index(othersheet!$c$1:$c$100,match(1,(a2=othersheet!$a$1:$a$100)*(b2=othersheet
!$b$1:$b$100),0))

would it not be something similar to this

=index(othersheet!$c$1:$c$100,match(1,(othersheet!$a$1:$a$100="2/2/6")*(othersheet
!$b$1:$b$100="bob"),0))

?
 
D

Dave Peterson

Is that 2/2/6 a date?

if yes and it means February 2, 2006, then maybe:

=index(othersheet!$c$1:$c$100,
match(1,(othersheet!$a$1:$a$100=date(2006,2,2))
*(othersheet!$b$1:$b$100="bob"),0))
 
Top