Formula works in google sheets but not in Excel, how to make it works?

P

Pat

=IF(D2="","",LOOKUP(D2,{0,4.99,9.99,24.99,99.99,1499.99},{"1","1.5","2.5",D2*0.1,(0.05*(D2-100))+10,(0.03*(D2-1500))+80}))

This formula works in google sheets but not in Excel on my PC.

How to make it works on Excel? "Using Excel 2007"

Thanks.
 
J

joeu2004

Pat said:
=IF(D2="","",LOOKUP(D2,{0,4.99,9.99,24.99,99.99,1499.99},
{"1","1.5","2.5",D2*0.1,(0.05*(D2-100))+10,(0.03*(D2-1500))+80}))
This formula works in google sheets but not in Excel on my PC.
How to make it works on Excel? "Using Excel 2007"

Try:

=IF(D2="","",CHOOSE(MATCH(D2,{0,4.99,9.99,24.99,99.99,1499.99}),
"1","1.5","2.5",D2*0.1,(0.05*(D2-100))+10,(0.03*(D2-1500))+80))

However, at a minimum, I think the following is better:

=IF(D2="","",CHOOSE(MATCH(D2,{0,4.99,9.99,24.99,99.99,1499.99}),
1,1.5,2.5,D2*0.1,0.(05*(D2-100))+10,(0.03*(D2-1500))+80))

I removed the double-quotes around the first 3 results so the formula
returns __numeric__ 1, 1.5 and 2.5 instead of __text__ "1", "1.5" and "2.5".
I presume that is what you intended.

Moreover, if D2 is calculated (a formula), the following might be more
reliable:

=IF(D2="","",CHOOSE(MATCH(ROUND(D2,2),
{0,4.99,9.99,24.99,99.99,1499.99}),
1,1.5,2.5,D2*0.1,0.(05*(D2-100))+10,(0.03*(D2-1500))+80))

The point is: D2 might __appear__ to be 4.99 due to formatting (e.g. Number
with 2 decimal places), but its __actual__ value might be less, for example
4.989.

In that case, you need to use ROUND(...,2) if you want to treat D2 as it
__appears__ (4.99).

Alternatively, you might use ROUND(...,2) in the formula in D2 instead.
Whether or not that is correct to do depends on the design of your
worksheet.

That is true for Google Sheets as well as Excel.
 
M

Martin Brown

Try 2003 or earlier it will probably work OK there.
Try:

=IF(D2="","",CHOOSE(MATCH(D2,{0,4.99,9.99,24.99,99.99,1499.99}),
"1","1.5","2.5",D2*0.1,(0.05*(D2-100))+10,(0.03*(D2-1500))+80))

However, at a minimum, I think the following is better:

=IF(D2="","",CHOOSE(MATCH(D2,{0,4.99,9.99,24.99,99.99,1499.99}),
1,1.5,2.5,D2*0.1,0.(05*(D2-100))+10,(0.03*(D2-1500))+80))

I removed the double-quotes around the first 3 results so the formula
returns __numeric__ 1, 1.5 and 2.5 instead of __text__ "1", "1.5" and
"2.5". I presume that is what you intended.

Moreover, if D2 is calculated (a formula), the following might be more
reliable:

=IF(D2="","",CHOOSE(MATCH(ROUND(D2,2),
{0,4.99,9.99,24.99,99.99,1499.99}),
1,1.5,2.5,D2*0.1,0.(05*(D2-100))+10,(0.03*(D2-1500))+80))

The point is: D2 might __appear__ to be 4.99 due to formatting (e.g.
Number with 2 decimal places), but its __actual__ value might be less,
for example 4.989.

In that case, you need to use ROUND(...,2) if you want to treat D2 as it
__appears__ (4.99).

Alternatively, you might use ROUND(...,2) in the formula in D2 instead.
Whether or not that is correct to do depends on the design of your
worksheet.

That is true for Google Sheets as well as Excel.

When I try it in XL2010 it faults any attempt to put a formula in the
results array list. It only accepts simple manifest constants.

It won't accept PI() for instance.
 
J

joeu2004

Martin Brown said:
Try 2003 or earlier it will probably work OK there.

No it doesn't. At least, not in Excel 2003.


Martin Brown said:
=IF(D2="","",CHOOSE(MATCH(D2,{0,4.99,9.99,24.99,99.99,1499.99}),
"1","1.5","2.5",D2*0.1,(0.05*(D2-100))+10,(0.03*(D2-1500))+80))
[....]
When I try it in XL2010 it faults any attempt to put a formula
in the results array list. It only accepts simple manifest constants.

..... Which is why I effectively replaced LOOKUP with CHOOSE.

From the Excel LOOKUP help page:

[BEGIN QUOTE]
LOOKUP(lookup_value,lookup_vector,result_vector)

Lookup_value is a value that LOOKUP searches for in the first vector.
Lookup_value can be a number, text, a logical value, or a name or reference
that refers to a value.

Lookup_vector is a range that contains only one row or one column. The
values in lookup_vector can be text, numbers, or logical values.
[END QUOTE]

"Text, number or logical values". Nothing there about expressions. A
little experimentation would have confirmed:

=LOOKUP(5,{0,4.99,10},{1,2,3})

works, but:

=LOOKUP(5,{0,4.99,10},{1,2+0,3})

raises a syntax error.
 

Ask a Question

Want to reply to this thread or ask your own question?

You'll need to choose a username for the site, which only take a couple of moments. After that, you can post your question and our members will help you out.

Ask a Question

Top