How do you write an excel formula to sum data in every second cell

  • Thread starter Sarah needs to know
  • Start date
S

Sarah needs to know

I have a list of numbers all in one column and I want to be able to type in a
formula that will SUM the numbers in every second cell only, without having
to click on each cell individually. This is how I do it now,
=sum(a1+a3+a5+a7+a9+....etc). Is there a formula that will tell excel to do
this automattically? If so can you tell me how to do it?
 
G

Gary''s Student

Say your data is in column A and in column B you enter:

=ISEVEN(ROW()+1)*1 and copy down. Then =SUMPRODUCT(A1:A100,B1:B100) will
get your desired result for 100 items.
 
D

Dana DeLouis

=sum(a1+a3+a5+a7+a9+....etc).

Just another option. If Rng is defined similar to A1:A100, then...

=SUMPRODUCT(--(MOD(ROW(Rng),2)=1),Rng)

( =0 to sum Even Rows)

HTH :>)
 
E

ellmcg

To keep it simple, I would use 2 more columns, the first with:
1
0
1
0
1
0
1
0

etc, and the second with: =A1*B1 etc. Then you can just use the sum
function on that column (and put the answer where-ever you want on the sheet).
 
P

Peo Sjoblom

One way

=SUMPRODUCT(--(MOD(ROW(A1:A100),2)=1),A1:A100)

--
Regards,

Peo Sjoblom

(No private emails please)
 
S

Sloth

I was playing around with these two functions...
=SUM((A1:A10)*(MOD(ROW(A1:A10),2)))
=SUMPRODUCT(A1:A10,MOD(ROW(A1:A10),2))

The first being an array function (you have to press ctrl+shift+enter). The
are both similar to answers already submitted, but I had a question. With
both of these functions I have to use a specified range, I can't use the
whole colum A:A. Why is this?
 
Top