How to insert an image file (eg. jpeg,gif) after protect the worksheet?

H

HIV.beta

hi all,
first, i want to protect(or lock) my worksheet;
second, i need to insert image file into the protected worksheet.
third, i just want to know how ?

help me.
 
H

HIV.beta

"allow objects to be changed" allow you to change the
status(width,length,color,etc.) of the existing images. but it does not
allow you to insert a NEW ONE.
 
D

Dave Peterson

Yep. You're correct.

Unprotect the sheet, add the picture, reprotect the sheet.

Or set up a macro that does the same thing.
 
D

Dave Peterson

A little search of google...

Option Explicit
Sub testme02()

Dim myPictureName As Variant
Dim myPict As Picture
Dim myRng As Range

myPictureName = Application.GetOpenFilename _
(filefilter:="Picture Files,*.jpg;*.bmp;*.tif;*.gif")

If myPictureName = False Then
Exit Sub 'user hit cancel
End If

With Worksheets("sheet1")
.Unprotect Password:="hi"
Set myRng = .Range("A1:e10")
Set myPict = .Pictures.Insert(myPictureName)
myPict.Top = myRng.Top
myPict.Width = myRng.Width
myPict.Height = myRng.Height
myPict.Left = myRng.Left
myPict.Placement = xlMoveAndSize
.Protect Password:="hi"
End With
End Sub
 
Top