If a comma is found

[David P.]

How would I do this?:

=IF(A comma is found in A1),...

Thanks.

 

[Max]

=IF(A comma is found in A1),...

=IF(ISNUMBER(SEARCH(",",A1)), ...
--
Max
Singapore
http://savefile.com/projects/236895
Downloads:21,000 Files:365 Subscribers:65
xdemechanik
---

 

[T. Valko]

Another one:

=IF(COUNT(FIND(",",A1)),.....

Note that this doesn't work on numbers using a number comma format (10,000)

 

[Joerg Mochikun]

Assumes that A1 contains text:
=IF(ISERROR(FIND(",",A1)),"comma not found","comma found")

Joerg

 

[Rick Rothstein]

Here is another approach...

=IF(LEN(A1)=LEN(SUBSTITUTE(A1,",","")),"No comma","There's a comma")

 

[Dave Peterson]

One more:

=if(countif(a1,"*,*")>0,"found","not found")

 

[Rick Rothstein]

I like this one best... one function call. Let's remove the comparison just
to shorten it up a bit...

=IF(COUNTIF(A1,"*,*"),"found","not found")

 

[Dave Peterson]

I find using the comparison self-documenting.

I like this one best... one function call. Let's remove the comparison just
to shorten it up a bit...

=IF(COUNTIF(A1,"*,*"),"found","not found")

 

[Rick Rothstein]

That is true enough (but I would guess doing introduces an extra, albeit
very quick, calculation to the formula).

--
Rick (MVP - Excel)

I find using the comparison self-documenting.

 

[Dave Peterson]

I think it makes the formula easier to understand -- especially for the posters
who are asking this type of question.

And it may make it easier to use the function in different formulas.

That is true enough (but I would guess doing introduces an extra, albeit
very quick, calculation to the formula).