IF FUnctions that produce TEXT results

[Jafferi]

I have a list of grades that I need a formula to provide the results for
better immediate actions.
Results that shows:
If results is | Comment
1 Keep it up
2 Good
3 Require Monitoring
4 Require Coaching
5-6 Employee P-File and Close Coaching
above 6 Immediate Action, P-File and Coaching

I uses the following formula, but it does not work as it still shows as
Require monitoring no matter what the result is.

=IF(B12>=3,"Require Monitoring",(IF(B12=4,"Require
Coaching",(IF(B12=5,"Employee P-File & Coaching",IF(B12>6,"Immediate
Action_P-File_Coaching","Require Monitoring"))))))

 

[Jacob Skaria]

Alternate solution using LOOKUP
=LOOKUP(B12,{1,2,3,4,5,7},{"Keep it up","Good","Require Monitoring","Require
Coaching","Employee P-File and Close Coaching"," Immediate Action, P-File and
Coaching"})


If this post helps click Yes

 

[Jacob Skaria]

The problem with your formula is that if B12 is 4 that satisfies your first
condition itself...So returns Require Monitoring..

Try this.. The conditions are placed in a sequence...

=IF(B12>6,"Immediate Action, P-File and Coaching",IF(B12>4,"Employee P-File
and Close Coaching",IF(B12=4,"Require Coaching",IF(B12=3,"Require
Monitoring",IF(B12=2,"Good",IF(B12=1,"Keep it up",""))))))

 

[T. Valko]

Create a 2 column list with the number in the left column and the text in
the right column:

...........F..........G
1.......1......Keep it up
2.......2......Good
3.......3......Require Monitoring
4.......4......Require Coaching
5.......5......Employee P-File and Close Coaching
6.......7......Immediate Action, P-File and Coaching

Then use this formula:

=IF(N(B12),VLOOKUP(B12,F1:G6,2),"")