Is this possible?

V

vla

Hi all,

I'm not very experienced with Excel and I was wondering if it'
possible to set up a rule in a spreadsheet so that the last entry i
highlighted or in a different color.

Does anyone know?

Thanks!
Vla:confused
 
J

Jim May

If you mean you wish the current or active cell to be highlighted then paste
the following code into the Thisworkbook Module.

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, _
ByVal Target As Excel.Range)
On Error Resume Next
Sh.Cells.Interior.ColorIndex = xlColorIndexNone 'xlColorIndexNone
'or -4142
Target.Interior.ColorIndex = 6 ' yellow - change as needed
End Sub

HTH
 
B

Bob Phillips

'----------------------------------------------------------------
Private Sub Worksheet_Change(ByVal Target As Range)
'----------------------------------------------------------------
Static prevCell As Range
Static prevCellCI As Long
On Error GoTo ws_exit
Application.EnableEvents = False
If Not prevCell Is Nothing Then
prevCell.Interior.ColorIndex = prevCellCI
End If
Set prevCell = Target
prevCellCI = Target.Interior.ColorIndex
Target.Interior.ColorIndex = 34

ws_exit:
Application.EnableEvents = True
End Sub

'This is worksheet event code, which means that it needs to be
'placed in the appropriate worksheet code module, not a standard
'code module. To do this, right-click on the sheet tab, select
'the View Code option from the menu, and paste the code in.


--

HTH

Bob Phillips

(remove nothere from the email address if mailing direct)
 
J

Jim May

Yes, instead of the patterns tab (where you select the color of the
background) select the Font Tab.. there
you will see the Color Option (Pick one). and OK out.
 
B

Bob Phillips

Yes, just change Interior to Font

'----------------------------------------------------------------
Private Sub Worksheet_Change(ByVal Target As Range)
'----------------------------------------------------------------
Static prevCell As Range
Static prevCellCI As Long
On Error GoTo ws_exit
Application.EnableEvents = False
If Not prevCell Is Nothing Then
prevCell.Font.ColorIndex = prevCellCI
End If
Set prevCell = Target
prevCellCI = Target.Font.ColorIndex
Target.Font.ColorIndex = 34

ws_exit:
Application.EnableEvents = True
End Sub


--

HTH

Bob Phillips

(remove nothere from the email address if mailing direct)
 
Top