LAST PIECE OF DATA

F

ftahbaz

How can I get a vlookup (or another function) to look for the DATA in
the last row in of a column.

For ex... have data in column A... rows 1-5 have data filled in.

How can I get it to tell me what is in A5?

And tomorrow when I fill in data in row 6, how can I get it to
automatically report that data?
 
D

Don Guillett

just find a number or letter ("zzzzzz") larger possible
=INDEX(A:A,MATCH(9999999,A:A),1)
 
G

Gord Dibben

Several different formulas.

=LOOKUP(9.99999999999999E+307,F:F) will return last numeric data in column F

=LOOKUP(REPT("z",255),B2:B10000) will return last non-numeric data in column B

=LOOKUP(2,1/(A1:A65516<>""),A1:A65516) will return last anything in column A


Gord Dibben MS Excel MVP
 
M

Max

Gord Dibben said:
=LOOKUP(2,1/(A1:A65516<>""),A1:A65516) will return last anything in
column A
Click to expand...
Think that'll miss out what's possibly within A65517:A65535/6 <g>.
Perhaps either:
=LOOKUP(2,1/(A1:A65535<>""),A1:A65535)
=LOOKUP(2,1/(A2:A65536<>""),A2:A65536)
 
G

Gord Dibben

Thanks Max

'Nother one of those typos.


Gord

Think that'll miss out what's possibly within A65517:A65535/6 <g>.
Perhaps either:
=LOOKUP(2,1/(A1:A65535<>""),A1:A65535)
=LOOKUP(2,1/(A2:A65536<>""),A2:A65536)
Click to expand...

Gord Dibben MS Excel MVP
 
Top