Last row value to another sheet

T

Ted Dawson

On one worksheet, I have several rows. Each time a new row of data is added,
I need to take the value from column B in the last row and display it in a
D3 on another worksheet. Can anyone help get me started?


Ted
 
T

Ted Dawson

No, I need the value from a column in whatever row is the most recent, the
last row which changes every so often. In other words, a row with new data
is entered every week, from this row, the last row with data in it....


Ted
 
B

Biff

Try this:

=LOOKUP(9.99999999999999E+307,Sheet1!B:B)

Change the sheet name as needed.

Biff
 
T

Ted Dawson

OK, I get it now. Thank you.

Next question: Now I need to add together the last TWO cells in a particular
column... can we do that?


Ted
 
B

Biff

add together the last TWO cells in a particular column

Will they always be contiguous?

Like this:

25
50

Or might there be blank cells in-between:

25

50

Biff
 
T

Ted Dawson

They should always be contiguous, but if you care to school all of us in
both scenarios...


Ted
 
B

Biff

If they're contiguous:

=SUM(OFFSET(B1,MAX(2,COUNT(B:B))-1,,-2))

If there might be blank or empty cells within the range: (it's a little more
complicated!):

Entered as an array using the key conbo of CTRL,SHIFT,ENTER:

=IF(COUNT(B1:B100)<1,0,SUM(B100:INDEX(B1:B100,LARGE(IF(B1:B100<>"",ROW(B1:B100)),MIN(2,COUNT(B1:B100))))))

Biff

In this array formula you can't use entire columns as a range reference (in
certain expressions). I used a range of B1:B100. You don't need to know the
last entry is in B100 but just use a big enough range to cover the last
entry.
 
A

Aladin Akyurek

Define BigNum as referring to 9.99999999999999E+307 then invoke:

=LOOKUP(BigNum,B2:B65536)+
LOOKUP(BigNum,B2:INDEX(B2:B65536,
MATCH(BigNum,B2:B65536)-1))
 
Top