Need help with =IF formula

[Harvey]

I need a formula to do this: if the sale is less than $100 the commission is
15% of the sale, if the sale is less then $200 the commission is 15% on the
first hundred + 10% of the balance of the sale, and if the sale is over $200
the commission is 15% of the first $100 , 10% of the second $100 and 5% for
anything over $200.

I came up with =IF(D9<100,".15",IF(D9<200,".1","")) which does not come near
to what I need.

I need help, I am using Excel 2002.

Harvey Mandel

 

[PCLIVE]

Maybe something like this:

=IF(A1<100,A1*0.15,IF(A1<200,(100*0.15)+((A1-100)*0.1),(100*0.15)+(100*0.1)+((A1-200)*0.05)))

HTH,
Paul

 

[Toppers]

Try:

=IF(A2<=100,A2*0.15,IF(A2<=200,15+(A2-100)*0.1,25+(A2-200)*0.05))

A2=Sale value

Not I have assumed less than or equal to 100, 200: change if needed

 

[Mark Lincoln]

I came up with a bit shorter version:

=IF(D9<=100,D9*0.15,IF(D9<=200,15+(D9-100)*0.1,25+(D9-200)*0.05))

Mark Lincoln

 

[CLR]

=IF(A1>200,25+(0.05*(A1-200)),IF(A1>100,15+(0.1*(A1-100)),IF(A1<=100,(0.15*A1))))

Vaya con Dios,
Chuck, CABGx3

 

[Niek Otten]

Hi Harvey,

Look here for a generic solution:

http://www.mcgimpsey.com/excel/variablerate.html


--
Kind regards,

Niek Otten
Microsoft MVP - Excel

|I need a formula to do this: if the sale is less than $100 the commission is
| 15% of the sale, if the sale is less then $200 the commission is 15% on the
| first hundred + 10% of the balance of the sale, and if the sale is over $200
| the commission is 15% of the first $100 , 10% of the second $100 and 5% for
| anything over $200.
|
| I came up with =IF(D9<100,".15",IF(D9<200,".1","")) which does not come near
| to what I need.
|
| I need help, I am using Excel 2002.
|
| Harvey Mandel
|
|

 

[Harvey]

Paul, Thank you and all who responded to my request for help -- the formula
worked perfectly.

Harvey