Picking Values from a list

B

babygoode

Hi,

I have a list of data which I need to pick out each individual entry
from but some of the data will be duplicated and I only need to pick it
out once. Is this possible?

ColumnA Column B
A
B
C
A
D
C

So in column B i want to list the data but I only want A and D and C to
show once?

Thanks,
Max
 
B

Bob Phillips

Needs an intermediate column

in B1, add this formula

=IF(COUNTIF($A$1:A1,A1)=1,ROW(A1),"")

in C1 add this

=IF(ROW(A1)-ROW(A$1)+1>COUNT(B$1:B$6),"",
INDEX(A:A,SMALL(B$1:B$6,1+ROW(A1)-ROW(A$1))))

then copy B1 and C1 down. Adjust the last cell, B$6, to suit

--

HTH

RP
(remove nothere from the email address if mailing direct)
 
B

Bob Phillips

Oh, or you could use Filter>Advanced Filter which has a Unique Records
facility.

--

HTH

RP
(remove nothere from the email address if mailing direct)
 
D

Domenic

Assuming that A1:A6 contains your data, try the following...

1) Leave B1 blank

2) Enter the following formula in B2, and copy down:

=IF(OR(COUNTIF($B$1:B1,A1:$A$6)=0),INDEX(A1:$A$6,MATCH(0,COUNTIF($B$1:B1,
A1:$A$6),0)),"")

....confirmed with CONTROL+SHIFT+ENTER, not just ENTER.

Hope this helps!
 
Top