Print a list of symbols

[ishh]

How do I print a list showing all symbols available under the Insert - symbol
menu?

 

[Jon]

I suggest making screenshots and printing from that.

 

[Klaus Linke]

How do I print a list showing all symbols available under the
Insert - symbol menu?

The list can be different for each font. And some fonts contain thousands of
symbols, so you would need tons of paper.

If you need such a list professionally, you might spend some bucks on the
Unicode Standard:
http://www.amazon.com/exec/obidos/ASIN/0321185781/103-7003750-0594221

You can also find it online, and maybe print out a couple of pages that are of
special interest to you:
http://www.unicode.org/standard/where/

That won't show you the characters from symbol fonts like Wingdings or Symbol
(though those same symbols are often available in large "regular" fonts, too).

Regards,
Klaus

 

[Suzanne S. Barnhill]

For genuine symbol fonts (which are limited to ASCII characters 32 to 255),
I make a table with 32 rows and 14 columns (seven pairs). In each pair of
columns, I format the lefthand column as Times New Roman or Arial and the
righthand column in the desired symbol font. In each pair of cells, I type a
number in the left cell (32 to 63 in the first column, 64 to 95 in the
third, etc.). In the right cell I press Alt+0xxx, where xxx is the number,
032 to 255, corresponding to the number in the left cell. The result is a
chart of all the symbols in that font.

This is quite tedious for the first symbol font, but for any other, all you
have to do is change the font in the even-numbered columns.

 

[Klaus Linke]

This is quite tedious for the first symbol font, but for any other, all

you have to do is change the font in the even-numbered columns.

And if you have used a style, you only need to change that.

Below's a macro for creating such a table...
It shows the symbol characters, the corresponding "regular" character, decimal
and hexadecimal code.

You'd need to change the "symbol font" character style to some font (like
Wingdings, Zapf Dingbats, European Pi...).

Regards,
Klaus


Sub CharTable()

Dim i As Long

On Error Resume Next
ActiveDocument.Styles.Add Name:="symbol font", _
Type:=wdStyleTypeCharacter
On Error GoTo 0
With ActiveDocument.Styles("symbol font").Font
.Name = "Symbol"
.Size = 8
End With
With ActiveDocument.Styles(wdStyleNormal).Font
.Name = "Times New Roman"
.Size = 8
End With

ActiveDocument.Tables.Add Range:=Selection.Range, _
NumRows:=56, NumColumns:=16, _
DefaultTableBehavior:=wdWord9TableBehavior, _
AutoFitBehavior:=wdAutoFitFixed
Selection.Tables(1).AutoFitBehavior (wdAutoFitWindow)
Selection.Cells.DistributeWidth
With Selection.Tables(1)
.TopPadding = CentimetersToPoints(0)
.BottomPadding = CentimetersToPoints(0)
.LeftPadding = CentimetersToPoints(0)
.RightPadding = CentimetersToPoints(0)
.Spacing = 0
.AllowPageBreaks = True
.AllowAutoFit = True
End With
Selection.Tables(1).Cell(1, 1).Select
For i = 32 To 255
Selection.InsertAfter Chr(i)
Selection.Style = ActiveDocument.Styles("symbol font")
With Selection.Cells(1).Shading
.Texture = wdTextureNone
.ForegroundPatternColor = wdColorAutomatic
.BackgroundPatternColor = wdColorLightYellow
End With
With Selection.Cells(1).Borders(wdBorderRight)
.LineStyle = wdLineStyleNone
End With
With Selection.Cells(1).Borders(wdBorderBottom)
.LineStyle = wdLineStyleNone
End With
Selection.Move Unit:=wdCell, Count:=1
Selection.Style = ActiveDocument.Styles(wdStyleNormal)
Selection.InsertAfter Chr(i)
With Selection.Cells(1).Shading
.Texture = wdTextureNone
.ForegroundPatternColor = wdColorAutomatic
.BackgroundPatternColor = wdColorGray10
End With
With Selection.Cells(1).Borders(wdBorderLeft)
.LineStyle = wdLineStyleNone
End With
With Selection.Cells(1).Borders(wdBorderBottom)
.LineStyle = wdLineStyleNone
End With
If i < 255 Then
Selection.Move Unit:=wdCell
End If
If i Mod 8 = 7 Then
Selection.Move Unit:=wdRow
End If
Next i
Selection.Tables(1).Cell(2, 1).Select
For i = 32 To 255
If i > 127 Then
Selection.InsertAfter "0"
End If
Selection.InsertAfter str(i)
With Selection.Cells(1).Borders(wdBorderRight)
.LineStyle = wdLineStyleNone
End With
Selection.Move Unit:=wdCell
Selection.InsertAfter "H" & Hex(i)

If i < 255 Then
Selection.Move Unit:=wdCell
End If
If i Mod 8 = 7 Then
Selection.Move Unit:=wdRow
End If
Next i
Selection.Tables(1).Select
Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
End Sub