Property information

G

George

Perhaps you'll have better luck getting an appropriate answer by contacting
the operators of that website to see if they offer any support or
instructions on using their service.

You have posted your question in a discussion group devoted to support of MS
Access, the relational database product which is part of the MS Office Suite
of applications. The website is not all that clear and may have misled you.
 
G

George

Perhaps you'll have better luck getting an appropriate answer by contacting
the operators of that website to see if they offer any support or
instructions on using their service.

You have posted your question in a discussion group devoted to support of MS
Access, the relational database product which is part of the MS Office Suite
of applications. The website is not all that clear and may have misled you.
 
T

Tom Wickerath

It looks like you just need some simple VBA code, to concatentate the proper
values together. Assuming you have two textboxes on your form, one showing
just the Street Number and one with the Street Name, and a command button on
the form, you might do something like this:

Option Compare Database
Option Explicit

Private Sub cmdPropertySearch_Click()
On Error GoTo ProcError

Dim strLink As String

'Save record, if dirty
If Me.Dirty = True Then
Me.Dirty = False
End If

'Check for street number and street name entries
If Len([StreetNumber] & "") = 0 Then
MsgBox "You must enter a street number.", _
vbInformation, "Unknown Street Number..."
Me.StreetNumber.SetFocus
GoTo ExitProc
End If

If Len([StreetName] & "") = 0 Then
MsgBox "You must enter a street name.", _
vbInformation, "Unknown Street Name..."
Me.StreetName.SetFocus
GoTo ExitProc
End If

strLink = "http://sdatcert3.resiusa.org/" _
& "rp_rewrite/results.aspx?" _
& "County=03&SearchType=STREET&" _
& "StreetNumber=" & StreetNumber & "&" _
& "StreetName=" & StreetName & ""

'Debug.Print strLink

Application.FollowHyperlink strLink


ExitProc:
Exit Sub
ProcError:
MsgBox "Error " & Err.Number & ": " & Err.Description, _
vbCritical, "Error in procedure cmdPropertySearch_Click..."
Resume ExitProc
End Sub


Note: You can uncomment the Debug.Print statement and comment out the
Application.FollowHyperlink line of code, in order to print the concatenated
value to the Immediate Window (view with <Ctrl><G>, ie. hold down the Control
and G keys at the same time).


Tom Wickerath
Microsoft Access MVP
http://www.accessmvp.com/TWickerath/
http://www.access.qbuilt.com/html/expert_contributors.html
__________________________________________
 
I

ianc

I assume you want to search for an address held in your database. I've done
something similar with a post code search using an embeded web browser.

You'll need to insert a web browser activeX control into a form.
Tools>Insert ActiveC Control>Microsoft Web Browser. Then run the following
code. I've assumed here that the browser will be in a separate form and the
code is run when the form is loaded.

****************************************************
Private Sub Form_Load()
Dim objIE As SHDocVw.InternetExplorer
Set objIE = Me.myBrowser.Object
'myBrowser is the name of you browser ActiveX object
Dim x As Integer


'navigate to a URL
objIE.Navigate2
"http://sdatcert3.resiusa.org/rp_rewrite/searchtype.aspx?County=03&SearchType=street"

'wait for the browser to load
Do While objIE.ReadyState <> READYSTATE_COMPLETE
DoEvents
Loop

objIE.Document.Forms(0).streetNumber.Value = "20" ' replace with your
field value

objIE.Document.Forms(0).streetName.Value = "preston" ' replace with your
field value


'find the search button and click it
For x = 0 To objIE.Document.Forms(0).length - 1
If objIE.Document.Forms(0)(x).Type = "submit" Then
If objIE.Document.Forms(0)(x).Value = "SEARCH" Then
objIE.Document.Forms(0)(x).Click
Exit For
End If
End If
Next x

End Sub
***************************************************

"streetNumber" and "streetNname" are the text box values of the web page
form.

Hope this helps

Ian
 
K

KARL DEWEY

This forum is for Microsoft Access, a relational database that is part of
Microsoft Office Professional suite.
 
T

tedmi

This newsgroup is for questions relating to Microsoft Access, a relational
database product. Your question has nothing to do with same. You may want to
seek assistance from MD state websites.
 
Top