split text and numbers into separate cells

[Julie]

Hi everyone
I have a column that has text and numbers (name and phone number) in example
Julie 01264 000000.

I need to be able to split out the telephone number into another column can
anyone help?

Thanks in advance

Julie

 

[Jacob Skaria]

Hi Julie

Option1: From menu Data>Text to columns>Space delimiter..

Option2: (If space between name and number) With data in cell A1; in cell B1
enter the formula
=MID(A1,FIND(CHAR(32),A1)+1,LEN(A1))

Option3: Incase you dont have space between name and phone number
Please note that this is an array formula. Within the cell in edit mode (F2)
paste this formula and press Ctrl+Shift+Enter to apply this formula. If
successful in 'Formula Bar' you can notice the curly braces at both ends like
"{=<formula>}"

=MID(A1,MIN(SEARCH({0,1,2,3,4,5,6,7,8,9},A1&"0123456789")),LEN(A1))


If this post helps click Yes

 

[Simon Lloyd]

Is there always one name or two?, is there always a space in between th
numbers

Hi everyon
I have a column that has text and numbers (name and phone number) i
exampl
Julie 01264 000000

I need to be able to split out the telephone number into another colum
ca
anyone help

Thanks in advanc

Juli

--
Simon Lloy

Regards
Simon Lloy
'Microsoft Office Help' (http://www.thecodecage.com

 

[Jacob Skaria]

A small correction

Option3 is not an array formula..Normal entered...suppose your name is
'Jacob Skaria 1234' the first two options will not work... option3 will work..

=MID(A1,MIN(SEARCH({0,1,2,3,4,5,6,7,8,9},A1&"0123456789")),LEN(A1))

 

[Sean Timmons]

Or, if it's only name and phone #,

=LEFT(A2,FIND(" ",A2)-1)
Gets name

=RIGHT(A2,LEN(A2)-FIND(" ",A2))
Gets Number

 

[Ron Rosenfeld]

Hi everyone
I have a column that has text and numbers (name and phone number) in example
Julie 01264 000000.

I need to be able to split out the telephone number into another column can
anyone help?

Thanks in advance

Julie

So long as there are no digits within the name:

A1: Julie 01264 000000

Name:
=TRIM(LEFT(A1,MIN(SEARCH({1,2,3,4,5,6,7,8,9,0},A1&"1,2,3,4,5,6,7,8,9,0"))-1))

Digits:
=MID(A1,MIN(SEARCH({1,2,3,4,5,6,7,8,9,0},A1&"1,2,3,4,5,6,7,8,9,0")),99)
--ron