Statistics and Excel

J

James7100

Hi

I'm starting on a course in statistics and we have to do a lot of index
numbers. Now Excel is good at this as long as the indexes are simple.

But I can't figure out how to do Laspeyres, Paasche and Fisher indexes using
Excel. Any Ideas?

:) Klaus
 
B

bj

if your "baskets" are well defined in both the laspeyeres and Paasche
scenereos,
=sum(basket2)/sum(basket1) on each set of baskets will do the job
and the fisher index is the just the square root of the product of the other
2.
 
H

Harlan Grove

James7100 said:
I'm starting on a course in statistics and we have to do a lot of index
numbers. Now Excel is good at this as long as the indexes are simple.

But I can't figure out how to do Laspeyres, Paasche and Fisher indexes
using Excel. Any Ideas?
Click to expand...

Assuming this is a serious question, Wikipedia seems to provide correct
definitions.

http://en.wikipedia.org/wiki/Price_index#Paasche_and_Laspeyres_price_indices

So SUMPRODUCT is the only function needed.

Laspeyres:
=SUMPRODUCT(Prices_thisperiod,Quantities_baseperiod)
/SUMPRODUCT(Prices_baseperiod,Quantities_baseperiod)

Paasche:
=SUMPRODUCT(Prices_thisperiod,Quantities_thisperiod)
/SUMPRODUCT(Prices_baseperiod,Quantities_thisperiod)

Fischer:
=GEOMEAN(LaspeyresIndex,PaascheIndex)

and, FTHOI, Marshall-Edgeworth:
=SUMPRODUCT(Prices_thisperiod,(Quantities_baseperiod+Quantities_thisperiod))
/SUMPRODUCT(Prices_baseperiod,(Quantities_baseperiod+Quantities_thisperiod))
 
Top