Sumproduct +

K

Karen Smith

Here's the formula that I have now.

=SUMPRODUCT(--(pseries!$I$8:$I$4000="advertising"),--(pseries!$S$8:$S$4000<=30),pseries!$T$8:$T$4000)

I need to make formulas for >30 <=60, then >60 <=90, etc so on down the road
every 30 days.

I've tried the one below but it doesn't seem to give me the answer.
=SUMPRODUCT(--(pseries!$I$8:$I$4000="advertising"),--(pseries!$S$8:$S$4000>31<61),pseries!$T$8:$T$4000)
 
P

Peo Sjoblom

You need to use 2 separate ranges

=SUMPRODUCT(--(pseries!$I$8:$I$4000="advertising"),--(pseries!$S$8:$S$4000>31),--(pseries!$S$8:$S$4000<61),pseries!$T$8:$T$4000)


--


Regards,

Peo Sjoblom

Excel 95 - Excel 2007
Northwest Excel Solutions
www.nwexcelsolutions.com
(Remove ^^ from email)
 
B

Bob Umlas

=SUMPRODUCT(--(pseries!$I$8:$I$4000="advertising"),--(pseries!$S$8:$S$4000>3
0),--(pseries!$S$8:$S$4000<=60),pseries!$T$8:$T$4000)
etc.
 
P

Pete_UK

Hi Karen,

I think you will need to do:

=SUMPRODUCT((pseries!$I$8:$I$4000="advertising")*(pseries!$S$8:$S$4000>30)*(pseries!$S$8:$S$4000<=60),pseries!$T$8:$T$4000)

then change the 30 and 60 to 60 and 90 etc. You could put 30, 60, 90
etc in successive cells, then change the constants in the formula to
point to the cells.

Hope this helps.

Pete
 
Top