I would assume that the first thing you're looking to do is create a list of
uniques.
Then, reference this list to complete the count of each value in the list.
To create the unique list:
Say your salary list was in A1 to A2000.
In B1 enter"
=A1
In B2, enter this *array* formula:
=IF(ISERROR(MATCH(0,COUNTIF(B$1:B1,$A$1:$A$2000&""),0)),"",INDEX(IF(ISBLANK($A$1:$A$2000),"",$A$1:$A$2000),MATCH(0,COUNTIF(B$1:B1,$A$1:$A$2000&""),0)))
--
Array formulas are entered using CSE, <Ctrl> <Shift> <Enter>, instead of the
regular <Enter>, which will *automatically* enclose the formula in curly
brackets, which *cannot* be done manually. Also, CSE *must* be used when
revising the formula.
*AFTER* the CSE entry, drag down to copy as far as there are returns (no
blanks cells).
To count the occurrences of each value in the unique list:
Enter this formula in C1:
=IF(B1<>"",COUNTIF(A$1:A$2000,B1),"")
And drag down to copy as needed.
One problem that you might run into is that similar appearing values are
*not exactly identical*, and therefore will count as 2 values.
--
HTH,
RD
=====================================================
Please keep all correspondence within the Group, so all may benefit!
=====================================================
I've got a 2000 row worksheet (salaries) and I want to count the number of
occurences of each salary.
eg
15250 25
15855 1
16101 12
Can SKS help
Tx
Rob
