Windows in Taskbar

Q

Quahogboy

I am using MS Excel 2000 and Windows 2000. I like to have differen
worksheets in my taskbar as it's own icon so I can ALT-TAB back an
forth. When I open some worksheets it "turns off" this option. So
then need to go back to Tools=>Options=>Windows in Taskbar and put th
checkmark in.

Can someone explain to me why this happens and how I can always have i
default to staying checked? Thanks
 
H

Harald Staff

Hi

Use Ctrl F6 instead and you don't need the taskbar setting.

Tools > Options is a weird mixture of workbook settings and application
settings, and sometimes the workbook settings will set the application
settings (like with R1C1 style). So this may perhaps be the problem. Or
maybe a macro resets it.

HTH. Best wishes Harald
 
G

Gord Dibben

A known problem with Excel 2000.

From a posting by Debra Dalgleish.............

There's some information that may help in the following MSKB article:

OFF2000: Only One Icon Visible in Taskbar When "Windows in Taskbar"
Option Is Selected
http://support.microsoft.com/default.aspx?id=215816

End Debra post...........


Gord Dibben Excel MVP
 
D

Dave Peterson

Do you use Shared workbooks. If yes, there's a problem with that setting and
shared workbooks (but it's been fixed in xl2002--so that should help <bg>).

You could use an application event that resets that option each time a workbook
opens--until you upgrade:

You could use a workbook that reset this option each time you opened/created a
workbook.

If you like this idea:

Start a new workbook
Alt-F11 to get the VBE (where macros live)
hit ctrl-R to see the project explorer (a lot like windows explorer)
select your project (book1) VBAProject
right click and select Insert|Class Module
Then hit F4 (to see its properties)
Change the (name) property from Class1 to WinInTaskBar

Then paste this in that code window to the right:

Option Explicit
Public WithEvents xlApp As Excel.Application
Private Sub xlApp_NewWorkbook(ByVal Wb As Workbook)
Application.ShowWindowsInTaskbar = True
End Sub
Private Sub xlApp_WorkbookOpen(ByVal Wb As Workbook)
Application.ShowWindowsInTaskbar = True
End Sub


Now doubleclick on the ThisWorkbook object of this same project.
(you might have to expand all the levels to see it)

Paste this in the code window to the right.

Dim myWinInTaskBar As WinInTaskBar
Private Sub Workbook_Open()
Set myWinInTaskBar = New WinInTaskBar
Set myWinInTaskBar.xlApp = Application
End Sub
Private Sub Workbook_Close()
Set myWinInTaskBar.xlApp = Nothing
End Sub

Now back to excel and save your workbook--but save it as an addin and store it
in your XLStart folder.

By saving it as an addin, it'll be invisible to you when you're in excel. By
storing it in XLStart, your addin will load whenever you start excel.

If you're new to macros, you may want to read David McRitchie's intro at:
http://www.mvps.org/dmcritchie/excel/getstarted.htm
 
Top