Can I convert footnote numbers to text

[ingrid]

I'm working with a document where the author has used the automated endnote
facility in Word. Since this is about to be translated into Quark for
typesetting, I need the endnote marks and the numbers with the endnotes to be
real numbers, not endnote marks -- Quark will not read them as numbers.
I was sure I did the conversion using ActiveDocument.ConvertNumbersToText in
Visual Basic once before, but I can't seem to make it work. Help! There are
20 chapters with about 40 endnotes each.

 

[Stefan Blom]

ActiveDocument.ConvertNumbersToText only works with paragraph numbering (and
LISTNUM fields). For endnotes, you can use the following macro created by
MVP Doug Robbins:

Sub ConvertEndNotesToText()
'Created by Doug Robbins

Dim aendnote As Endnote


For Each aendnote In ActiveDocument.Endnotes


ActiveDocument.Range.InsertAfter _
vbCr & aendnote.Index & vbTab & aendnote.Range


aendnote.Reference.InsertBefore "a" & aendnote.Index & "a"


Next aendnote


For Each aendnote In ActiveDocument.Endnotes


aendnote.Reference.Delete


Next aendnote


Selection.Find.ClearFormatting


Selection.Find.Replacement.ClearFormatting


With Selection.Find.Replacement.Font


.Superscript = True


End With


With Selection.Find


.Text = "(a)([0-9]{1,})(a)"


.Replacement.Text = "\2"


.Forward = True


.Wrap = wdFindContinue


.Format = True


.MatchWildcards = True


End With


Selection.Find.Execute Replace:=wdReplaceAll

End Sub

If you need assistance, see http://www.gmayor.com/installing_macro.htm.