Need a "go-back-3-pages" Action Button Please

[Trip]

Hello all,

Any direction would be greatly appreciated.

I was hoping to create (non-programaticly) an action button which
always goes back three pages to be included on the slide master (this
will be used in the ppviewer and I don't want people to have to deal
with a macro warning, etc.) I'm looking to do this because I want the
animations to replay if someone hits the back button and I have found
that the only way to do that is to insert blank dummy-pages with a
transition time of 0.0 seconds. Thus, to go back one viewed-slide the
button would need to skip the blank page before the one that is
currently being viewd, skip the page that is wished to be viewd, and
land on the blank page just before the page to be viewed which will
then automaticly transition to the prefered page and begin the
animations again.

I don't want to have to go through each and every page and link to a
specific page. It becomes a maintenence nightmare.

Any suggsetions?

Thanks,

Trip

 

[Bill Dilworth]

By precluding VBA solutions, you have removed the easy solution, but I
understand the desire.

There is no Go Back 3 slides type of hyperlink that can be placed on the
Master, as you know.

Manually installing the hyperlinks would be a royal PIA.

So why not use a VBA/Macro solution to automate the creation of the 'goback
3 slides' hyperlinks on each of the slides?


-----Begin Code-----
Sub Back3Generator()

Dim oSld As Slide
Dim oShp As Shape

On Error GoTo Errored
For Each oSld In ActivePresentation.Slides
If oSld.SlideIndex > 3 Then
Set oShp = oSld.Shapes("GoBack3")
With oShp.ActionSettings(ppMouseClick)
.Hyperlink.Address = ""
.Hyperlink.SubAddress = _
ActivePresentation.Slides(oSld _
.SlideIndex - 3).SlideID & ",4 ,4"
End With
End If
Next oSld
Exit Sub

Errored:
With oSld.Shapes.AddShape _
(msoShapeActionButtonReturn, 10, 10, 30, 30)
.Name = "GoBack3"
.Fill.ForeColor.RGB = RGB(0, 175, 255)
End With
Resume

End Sub
-----End Code-----

One or two clicks on your end and the links are placed/updated. No VBA on
the other side, works within the viewer (without warnings), less filling, no
carbs, your mileage may vary.


--
Bill Dilworth
A proud member of the Microsoft PPT MVP Team
Users helping fellow users.
billdilworth.mvps.org
-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
yahoo2@ Please read the PowerPoint
yahoo. FAQ pages. They answer most
com of our questions.

..
..